? P&R Exercise 6.4
?  Revised to read ex64.xls
?  11/2000:  revised to remove extra square root in weight

OPTIONS CRT ;
TITLE 'US RESIDENTIAL ENERGY CONSUMPTION' ;
FREQ A;
SMPL 1960 1985;
?LIST VARS YEAR POPUL HSHLDS INCHH CPI PRELE PRGAS PROIL
?     PRQUAD QELE QGAS QOIL QTOT;
?READ(FILE='a:\ex3_data') VARS;
?MSD VARS;
?
?LQ = LOG(QTOT) ;
?LPQ = LOG(PRQUAD) ;
?LINC = LOG(HSHLDS)+LOG(INCHH) ;

read(file='ex64.xls') ;
LQ = LOG(Q) ;
LPQ = LOG(P) ;
LINC = LOG(INC) ;
trend YEAR 1960;

MSD LQ LPQ LINC ;

REGOPT(BPLIST=(C,YEAR),PVPRINT) BPHET ; ? AUTOMATE HS TEST.
OLSQ LQ C YEAR LPQ LINC ;
SET SSR0 = @SSR ;                 ? FOR USE IN (4)
SET DF0 = @NOB-@NCOEF ;

ESQ = @RES*@RES ;
OLSQ ESQ C YEAR ;
SET TRSQ = @NOB*@RSQ ;
CDF(CHISQ,DF=1) TRSQ ;


WT = 1/@FIT ;
MSD WT ;
WT = WT*(@FIT>.0001) + 10000*(@FIT<.0001) ;
?
?  Do not take the square root below.  OLSQ will take the square
?  root of the weight.  OLSQ expects the weight to be proportional
?  to the inverse variances of the residuals, which is already done
?  above with WT=1/@FIT (and setting negative or large values to 10000).
?  The results in the Pindyck & Rubinfeld book are based on taking
?  the square root too many times.
?  It does not affect the qualitative conclusions, though.
?
?WT = SQRT(WT);
OLSQ(WEIGHT=WT) LQ C YEAR LPQ LINC ;
EWT = @RES*SQRT(WT) ;

AR1 LQ C YEAR LPQ LINC ;
SET SSRAR = @SSR ; SET DFAR = @NOB-@NCOEF ;
ESQAR = @RES*@RES ;

SMPL 1960 1973 ;
OLSQ LQ C YEAR LPQ LINC ;
SET SSR1 = @SSR ; SET DF1 = @NOB-@NCOEF ;
SMPL 1974 1985 ;
OLSQ LQ C YEAR LPQ LINC ;
SET SSRU = SSR1+@SSR ; SET DFU = @NOB-@NCOEF+DF1 ;
SET Q = DF0-DFU ;
SET CHOWTEST = (SSR0-SSRU)/Q/(SSRU/DFU) ;
CDF(F,DF1=Q,DF2=DFU) CHOWTEST ;

SMPL 1960 1985 ;
REGOPT (CHOWDATE=1974,PVPRINT) CHOW ;
OLSQ LQ C YEAR LPQ LINC ;

OLSQ ESQAR C YEAR ;
SET TRSQAR = @NOB*@RSQ ;
CDF(CHISQ,DF=1) TRSQAR ;

SMPL 1961 1985 ;
OLSQ EWT C EWT(-1) ;
SET TRSQWT = @NOB*@RSQ ;
CDF(CHISQ,DF=1) TRSQWT ;


SMPL 1960 1985 ;
DOIL = YEAR>1973 ;
LINCOIL = LINC*DOIL ;
YEAROIL = YEAR*DOIL ;
AR1 LQ C DOIL YEAR YEAROIL LPQ LINC LINCOIL ;
SET SSRU = @SSR ; SET DFU = @NOB-@NCOEF ;
SET Q = DFAR-DFU ;
SET FSTAT = (SSRAR-SSRU)/Q/(SSRU/DFU) ;

CDF(F,DF1=Q,DF2=DFU) FSTAT ;

OLSQ LQ C DOIL YEAR YEAROIL LPQ LINC LINCOIL ;