? P&R Exercise 5.3

OPTIONS CRT ;
SUPRES SMPL ;
FREQ N;
SMPL 1 206;
LIST VAR2 = ED SOUTH NONWH HISP FE MARR MARFE EX EXSQ UNION 
LNWAGE AGE MANUF CONSTR MANAG SALES CLER SERV PROF;
READ(FILE='EX5.XLS') VAR2;
WAGE=EXP(LNWAGE);
OLSQ WAGE C FE;
SET DF1 = @NOB-@NCOEF ;
SET SSR1 = @SSR ;
SET TSTAT = @COEF(2)/@SES(2) ;
CDF(T,DF=DF1) TSTAT ;
OLSQ WAGE,C,FE,ED,AGE,NONWH,HISP;            
SET SSR2 = @SSR ;
SET DF2 = @NOB-@NCOEF ;
SET Q = DF1-DF2 ;
SET FSTAT = (SSR1-SSR2)/Q/(SSR2/DF2) ;

CDF (F,DF1=Q,DF2=DF2) FSTAT ;

AGESQ = AGE**2;
OLSQ WAGE,C,FE,ED,NONWH,HISP,AGE,AGESQ;          
SET DF3 = @NOB-@NCOEF ;
SET TSTAT = @COEF(7)/@SES(7) ;
CDF(T,DF=DF3,LOWTAIL) TSTAT ;

SET AGEMAX = -@COEF(6)/(2*@COEF(7)) ;
PRINT AGEMAX ;
SMPL 1 206 ;
OLSQ WAGE,C,ED,NONWH,HISP,AGE;                  
SET DF0 = @NOB-@NCOEF;
SET SSR0 = @SSR;

SELECT FE;
OLSQ WAGE,C,ED,NONWH,HISP,AGE;                       
SET DFF = @NOB-@NCOEF;
SET SSRF = @SSR;

SELECT ~FE;
OLSQ WAGE,C,ED,NONWH,HISP,AGE;                     
SET DFM = @NOB-@NCOEF;
SET SSRM = @SSR;

SET DFU = DFF+DFM ;
SET Q = DF0-DFU ;
SET CHOW = (SSR0-SSRF-SSRM)/Q/((SSRF+SSRM)/DFU);
CDF (F,DF1=Q,DF2=DFU) CHOW;
SELECT 1 ;
PRIM = MANAG | PROF ;  
SECOND = CLER | SERV ;

EXPRIM = EX*PRIM ;
SELECT PRIM | SECOND ;
OLSQ WAGE C PRIM ED EX EXPRIM ;  
SET DF5 = @NOB-@NCOEF ;
SET TSTAT = @COEF(5)/@SES(5) ;
CDF(T,DF=DF5) TSTAT ;

SMPL 1 206;
WHITCOLL = PRIM | CLER | SALES ;
REGOPT(PVPRINT) FST ;
OLSQ WAGE C FE NONWH HISP ED AGE WHITCOLL ;
OLSQ WAGE C ED AGE UNION ;
OLSQ WAGE C FE NONWH HISP ED AGE UNION ;
OLSQ WAGE C ED AGE SOUTH ;
OLSQ WAGE C FE NONWH HISP ED AGE SOUTH ;
EXSQ = EX*EX ;
OLSQ WAGE C FE NONWH HISP ED EX EXSQ ;
END;STOP;