options memory=10 crt limwarn=0 ;
?
? ========================= OLSTEST ===============================
?
?  One Variable Time Series Process Using Panel Data.
?  Use real data to investigate testing methodology.
?  OLS for unit root.
?
?  Bronwyn H. Hall - Hall and Mairesse 2001 (for Munich).
?
supres @covoc @smpl ;
read (file="/bhresearch/us/bchm/bchm.dta") ;

select scisect ;
const t 12 ;
set t1 = t-1 ;
trend = year-77 ;
sort (all,reverse) scisect year ;
select scisect ;
set nobt = @nob ;
print nobt ;
set nob = nobt/t ;
dot s r l i ;
  smpl 1 nobt ;
  y = log. ;
  mmake ymat y ;
  mform (nrow=t,ncol=nob) ymat ;
  mat ymat=ymat' ;
  select trend>1 ;
    dy = y-y(-1) ;
    mmake dymat dy ;
    mform (nrow=t1,ncol=nob) dymat ;
    mat dymat=dymat' ;
  smpl 1 nob ;
    unmake dymat dy79-dy89 ;
	unmake ymat y78-y89 ;
?	msd (corr) dy79-dy89 ;
?	msd (corr) y78-y89 ;
  frml eq89 dy89-a89-phi*y88 ;
  frml eq88 dy88-a88-phi*y87 ;
  frml eq87 dy87-a87-phi*y86 ;
  frml eq86 dy86-a86-phi*y85 ;
  frml eq85 dy85-a85-phi*y84 ;
  frml eq84 dy84-a84-phi*y83 ;
  frml eq83 dy83-a83-phi*y82 ;
  frml eq82 dy82-a82-phi*y81 ;  
  frml eq81 dy81-a81-phi*y80 ;
  frml eq80 dy80-a80-phi*y79 ;
  frml eq79 dy79-a79-phi*y78 ;
  param a79-a89 phi ;
  sur (silent,robust) eq79-eq89 ;
  msd y78-y89 ;
  tstat (names=@rnms) @coef @vcov ;
  lm2test lm1 lm2 ;
  cdf (normal) lm1 ;
  cdf (normal) lm2 ;
enddot ;