options double crt;
name gas12 'Gasoline data - 1-way, 2-way ML estimates';
?  Source: Baltagi and Griffin (1983).
?  Description: Panel Data, 18 OECD countries over 19 years, 1960-1978.
?  Variables:        
doc CO 'Country 1-18';
doc YR 'Year 1960-1978';
doc LGASPCAR
    'LN(Gas/Car): The logarithm of motor gasoline consumption per auto';
doc LINCOMEP 'LN(Y/N): The logarithm of real per-capita income';
doc LRPMG    'LN(Pmg/Pgdp): The logarithm of real motor gasoline price';
doc LCARPCAP 'LN(Car/N): The logarithm of the stock of cars per-capita';
list vars CO YR LGASPCAR LINCOMEP LRPMG LCARPCAP;
set n=18;
set t=19;
set nt=n*t;
smpl 1,nt;
read(file='gasoline.txt') vars;
freq(panel,id=CO,time=YR) ;
dummy(exclude) YR timedums;

title 'One-way ML, Two-way: Baltagi(2001) p.24,44';
list yx LGASPCAR LINCOMEP LRPMG LCARPCAP;
panel(rei,reit,tol=1e-7) yx;

title 'theta for One-way';
frml eqt theta = 1 - sqrt((1-rho_i)/(1+(T-1)*rho_i));
analyz(coef=@coefrei,vcov=@vcovrei,names=@rnmsrei) eqt;

title 'thetas for Two-way';
frml eqt1 theta1 = 1 - 1/sqrt(T*(rho_i/(1-rho_i-rho_t)) + 1);
frml eqt2 theta2 = 1 - 1/sqrt(N*(rho_t/(1-rho_i-rho_t)) + 1);
frml eqt3 theta3 = 1 - 1/sqrt(T*(rho_i/(1-rho_i-rho_t)) + 1)
                     - 1/sqrt(N*(rho_t/(1-rho_i-rho_t)) + 1)
                     + 1/sqrt(T*(rho_i/(1-rho_i-rho_t))
                     + N*(rho_t/(1-rho_i-rho_t)) + 1);
analyz(coef=@coefreit,vcov=@vcovreit,names=@rnmsreit) eqt1-eqt3;

title 'two-way within: p.44';
panel(notot,nobet,novarc) yx timedums;