options double crt nwidth=17,signif=11;
name bg11i 'GARCH(1,1) benchmark from Bollerslev-Ghysels JBES 4/96';
?  (computes Information Matrix and Bollerslev-Wooldridge SEs,
?   to reproduce results for these from FCP program)
?  by Clint Cummins 1/26/99
?   based on bg11.tsp.  Uses g11s.tsp .
?
?             FCP(VSGARCOV)            TSP 4.4         consensus SEs
?  gamma0                         -.00619040837994
?  (IMse)  (.008376285623751610)  (.00837628562687)  (.0083762856)
?  (BWse)  (.008730924687322440)  (.00873092468675)  (.008730924687)
?  alpha0                          .010761397852
?          (.001928808061104060)  (.00192880806004)  (.00192880806)
?          (.003123637505474058)  (.00312363750618)  (.00312363751)
?  alpha1                          .153134061820
?          (.01940118560429604)   (.019401185516)    (.019401186)
?          (.02732193405071940)   (.027321933999)    (.027321934)
?  beta1                           .805973670305
?          (.02183987222453894)   (.021839872164)    (.0218398722)
?          (.03015088596585329)   (.030150885923)    (.030150886)
?  LogL                           -1106.60788
?--------------------
?  Notes:
?  Parameter names used here (g11s.tsp):
?    alpha0 = sig0
?
?  y = Deutschmark-British Pound daily percentage nominal returns,
?      1/3/1984 - 12/31/1991
?      Obtained on 1/30/98 from   ftp  web.amstat.org
?      jbes/View/96-2-APR/bollerslev_ghysels/bollerslev.sec41.dat
smpl 1,1974;
read(file='dmbp.dat') y monday;

const ifhess,0;
input(noprint) 'g11s.tsp';   ? define model logl, derivatives, global variables

arch(hcov=wnb,tol=1e-11) y c;
unmake @coef gamma0 sig0 alpha1 beta1;
set init=2;   ?  use FCP initialization  h0 = (u'u)/T
initd;
dologl logl0;  ? computes h, u, etc. needed for derivatives
  print logl0 @logl;
? compute first log derivatives
?  dhda = (1/h)*dh/dalpha0 , for example
derivs;

?  matrix of first log derivatives ordered to agree with ARCH
mmake dlh dhdg dhds dhda dhdb;
mat im = (dlh'dlh)/2;
?  add x'x/h  term to (1,1) element
mat term = sum(1/h);
set im(1,1) = im(1,1) + term;
?  zero the off-diagonal block of IM
set im(2,1) = 0;
set im(3,1) = 0;
set im(4,1) = 0;
title 'Information Matrix SEs';
mat imi = im";
tstats(names=@rnms) @coef imi;

title 'Bollerslev-Wooldridge SEs';
mat bw = imi'@vcovb"imi;
tstats(names=@rnms) @coef bw;