OPTIONS CRT NODATE;
NAME TRADESOL '33 EQ TRADE MODEL - SOLVE WITH FLETCHER-POWELL METHOD' ;
?
?    1. GAUSS-SEIDEL CONVERGES CLOSE TO THE OPTIMUM.
?    2. FLPOW GIVES A FALSE CONVERGENCE TO A SADDLEPOINT.
?       SQZTOL=.001 IN 4.3 PREVENTS A FULL 50 ITERATIONS FROM BEING USED.
?    3. NEWTON DOESN'T CONVERGE (1ST PERIOD).
?    4. IF NEWTON (SIML) IS STARTED FROM THE GAUSS-SEIDEL ANSWERS,
?       IT CONVERGES IN 2 ITERATIONS.
?
?    READ IN THE DATA FOR THE TRADE MODEL.
?
FREQ A ; SMPL 64 73 ;
     READ (FILE='TRADESOL.DAT',FORMAT='(6G12.5)')
        ACDP AK AKD AKL CC CE
        CG DG DLDT DP DR E
        EI EJ EL ER ET EX
        G HLT HR I IG IM
        K KD L LD LE LG
        LH LJ LR LU M N
        NRE NW P PC PCE PCG
        PDP PEX PF PG PI PIG
        PIM PKD PL PLD PLE PLG
        PLR PR R RDP RE RIM RK
        RL RP RT RV RW SHRC
        SHRDP SHREX SHRFC SHRIM SHRKD T
        TDP TIM TK TL TP TV
        TW V VCR VIR W ;
?
?    SET THE CONSTANTS AND PARAMETERS FOR THE RUN.
?
SET NKD=166.92656 ;
SET NLD=252.81388 ;
SET NIM= 20.331 ;
SET NDP=419.56444 ;
SET NEX= 20.507 ;
SET  NT=  0.0 ;
SET  NL=  0.8464  ;
?
?    EQUATIONS OF THE 33 EQUATION MODEL.
?
IDENT IDSDP  DP=SHRDP*PLD*LD/PDP ;
? PROPER NORMALIZATION (BUT DOES NOT CONVERGE AS WELL):
?IDENT IDSIM PLD=-(PIM*IM)/(LD*SHRIM) ;
IDENT IDSIM  PL=PL+SHRIM+PIM*IM/(PLD*LD) ;
? PROPER NORMALIZATION:
?IDENT IDSKD  LD=-(PKD*KD)/(PLD*SHRKD) ;
IDENT IDSKD   L=L+SHRKD+PKD*KD/(PLD*LD) ;
IDENT IDSC   PC=(PL*LJ*SHRC)/(CC*(1-SHRC)) ;
IDENT IDSFC  CC=(SHRFC*(1+NW)*W(-1)-PL*LJ)/PC ;
IDENT IDF7  PDP=PC/ACDP ;
IDENT IDF8   LJ=LH-L ;
IDENT IDF9    N=(M*PI*AKL+PI(-1)*AK(-1)-PI*AKL
                -((1-TK)*((PKD*AKD)-TP*PI(-1)
            *AK(-1))))/(-PI(-1)*AK(-1)) ;
IDENT IDF10  NW=(-V-N*PI(-1)*AK(-1)*K(-1) + (PI*AKL-PI(-1)*AK(-1))*K(-1)
            -(1-TV)*(EI+VCR+VIR+NRE)-EJ+RV+TW*W(-1))/(-W(-1)) ;
IDENT IDF11 PEX=-(PDP*DP-PLD*LD-PKD*KD-PIM*IM)/EX ;
IDENT IDF12 IM = ((1+TDP)*PDP*DP-PC*CC+PCE*CE-PCG*CG-PIG*IG-PI*I)/
                 (-TIM*PIM)  ;
? DEPENDENT ON PROPER NORMALIZATION ABOVE:
?IDENT IDF13  PL=(PLD*LD+PLE*LE+PLG*LG+PLR*LR)*(1-TL)/L ;
IDENT IDF13 PLD=(PL*L/(1-TL)-PLE*LE-PLG*LG-PLR*LR)/LD ;
? DEPENDENT ON PROPER NORMALIZATION ABOVE:
?IDENT IDF14   L=LD+LE+LG+LR+LU ;
IDENT IDF14  LD=L-(LE+LG+LR+LU) ;
IDENT IDF16   R=(PEX*EX-PIM*IM+VCR+VIR+PLR*LR-ER-HR+NRE-ET)/PR+R(-1) ;
IDENT IDDG DG=E+EL+ER+EI+EJ-(RDP+RIM+RP+RK+RL+RW+RT+RE+RV);
IDENT IDDR DR=PEX*EX-PIM*IM+VCR+VIR-ER-HR+PLR*LR+NRE ;
IDENT IDE E=PCG*CG+PIG*IG+PLG*LG ;
IDENT IDG G=(DG+ET)/PG+G(-1) ;
IDENT IDKD KD=AKD*K(-1);
IDENT IDPF PF=PF(-1)*EXP(0.5*(
    ((PC*CC)/(PC*CC+PL*LJ)+(PC(-1)*CC(-1))/
    (PC(-1)*CC(-1)+PL(-1)*LJ(-1)))
   *LOG(PC/PC(-1))
   +((PL*LJ)/(PC*CC+PL*LJ)+(PL(-1)*LJ(-1))/
   (PC(-1)*CC(-1)+PL(-1)*LJ(-1)))
   *LOG(PL/PL(-1)))) ;
IDENT IDRDP RDP=TDP*PDP*DP ;
IDENT IDRE RE=PCE*CE-PLE*LE ;
IDENT IDRIM RIM=TIM*PIM*IM ;
IDENT IDRK RK=TK*(PKD*KD-RP)+TV*(EI+VCR+VIR+NRE);
IDENT IDRL RL=TL*(PLD*LD+PLE*LE+PLG*LG+PLR*LR);
IDENT IDRP RP=TP*PI(-1)*AK(-1)*K(-1);
IDENT IDRW RW=TW*W(-1);
IDENT IDV V=(PI*AKL-PI(-1)*AK(-1))*K(-1)+(PG-PG(-1))*G(-1)
             +(PR-PR(-1))*R(-1);
?
?     BEHAVIORAL EQUATIONS FOR THE CONSUMPTION SIDE OF THE MODEL AND
?  THEIR PARAMETER ESTIMATES.
?     SPECIFICATION: SYMMETRIC, CONVEXITY IMPOSED
?
FRML INTER1   SHRFC
     =((AX0+BON*LOG((PF*P)/
           ((1+NW)*W(-1)+LDA*(EL-HR-RT)+DEL*PL*LH))
           +BOT*(T-NT))/
     (-1+BNN*LOG((PF*P)/
           ((1+NW)*W(-1)+LDA*(EL-HR-RT)+DEL*PL*LH))
           +BNT*(T-NT)))*
     (1+(LDA*(EL-HR-RT)+DEL*PL*LH)/((1+NW)*W(-1)))$
FRML INTRA1 SHRC=AC+BCC*LOG(PC/(PL/NL)) ;
PARAM AX0 -.122007 BON -.0242706 LDA 7.85130 DEL 7.85130
   BNN -.197991 BNT .00143592 BOT .000149361 ;
PARAM AC .148803 BCC .0155448 ;
?
?     BEHAVIORAL EQUATIONS FOR THE PRODUCTION SIDE OF THE MODEL AND
?   THEIR PARAMETERS.
?
FRML CODP SHRDP=ADP+(LDPKD*DKD-AKS*ADP)*LOG((KD*NEX)/(NKD*EX))
          +(LDPKD*LDPKD*DKD+LDPIM*LDPIM*DIM+DDP
          -ADP*(ADP-1))*LOG((DP*NEX)/(NDP*EX))
          +BDPT*(T-NT);
FRML COKD SHRKD=AKS+(DKD-AKS*(AKS-1))*LOG((KD*NEX)/(NKD*EX))
          +(LIMKD*DKD-AKS*AIM)*LOG((IM*NEX)/(NIM*EX))
          +(LDPKD*DKD-AKS*ADP)*LOG((DP*NEX) /(NDP*EX))+BKDT*(T-NT);
FRML COIM SHRIM=AIM+(LIMKD*DKD-AKS*AIM)*LOG((KD*NEX)/(NKD*EX))
          +(LIMKD*LIMKD*DKD+DIM-AIM*(AIM-1))*LOG((IM*NEX)/(NIM*EX))
          +(LDPKD*LIMKD*DKD+LDPIM*DIM-AIM*ADP)*LOG((DP*NEX)/
          (NDP*EX))+BIMT*(T-NT) ;
FRML COT DLDT=AT+BKDT*LOG((KD*NEX)/(NKD*EX))+
          BIMT*LOG((IM*NEX)/(NIM*EX))
          +BDPT*LOG((DP*NEX)/(NDP*EX))+BTT*(T-NT);
PARAM AT -.02217 BTT .0001963 ;
PARAM AKS -.6373 DKD 1.260 LIMKD .0881 AIM -.0794
      LDPKD -1.020 ADP 1.638 ;
PARAM BKDT -.0046 DIM -.0262 LDPIM -.4053 BIMT .0006
      DDP .0320 BDPT .0048 ;
?
?      THIS IS THE LIST OF ENDOGENOUS VARIABLES IN THE MODEL.
?
LIST ENDOGL  E KD RE RP RW V N NW RK
             LJ LD PDP SHRC CC PF PLD    SHRDP SHRKD SHRIM
             L PL DP SHRFC PC
             PEX R DLDT DR RDP RIM RL DG G ;
?
?      THIS IS THE LIST OF EQUATIONS IN THE MODEL; THE ORDER CORRESPONDS
?   TO THE ORDER OF SOLUTION DESIRED.
?
LIST TRADEM IDE IDKD IDRE IDRP IDRW IDV IDF9 IDF10 IDRK
             IDF8 IDF14 IDF7 INTRA1 IDSFC IDPF IDF13
             CODP COKD COIM
                  IDSKD IDSIM IDSDP INTER1 IDSC
             IDF11 IDF16 COT IDDR IDRDP IDRIM IDRL IDDG IDG ;
?
?      THIS COLLECTION OF THE MODEL IS SUPERFLUOUS SINCE WE HAVE ALREADY
?   ACHIEVED THE DESIRED ORDERING.
?
COLECT TRADEM ENDOGL TRADEC ;
SMPL 65 66 ;
SOLVE(STATIC,TAG=S,MAXIT=80) TRADEC ;  PRINT @IFCONV;
SOLVE(STATIC,METHOD=FLPOW,TAG=F,MAXIT=50,SQZTOL=.001) TRADEC ;  PRINT @IFCONV;
?
?      SOLVE THE FIRST 2 BLOCKS (24 EQUATIONS) BY NEWTON'S METHOD.
?      (FIRST, WITH DEFAULT STARTING VALUES).
?
SIML (STATIC,ENDOG=(E KD RE RP RW V N NW RK
      LJ LD PDP SHRC CC PF PLD SHRDP SHRKD SHRIM L PL DP SHRFC PC))
     IDE IDKD IDRE IDRP IDRW IDV IDF9 IDF10 IDRK
     IDF8 IDF14 IDF7 INTRA1 IDSFC IDPF IDF13 CODP COKD COIM
     IDSKD IDSIM IDSDP INTER1 IDSC
     ;  PRINT @IFCONV;
?
?      SOLVE THE FIRST 2 BLOCKS (24 EQUATIONS) BY NEWTON'S METHOD.
?      (NOW, WITH STARTING VALUES FROM GAUSS-SEIDEL).
?
DOT E KD RE RP RW V N NW RK
    LJ LD PDP SHRC CC PF PLD SHRDP SHRKD SHRIM L PL DP SHRFC PC;
  .SAV = .;
  . = .S;   ? USE SOLVED VALUES AS STARTING VALUES
ENDDOT;
SIML (STATIC,TAG=N,ENDOG=(E KD RE RP RW V N NW RK
      LJ LD PDP SHRC CC PF PLD SHRDP SHRKD SHRIM L PL DP SHRFC PC))
     IDE IDKD IDRE IDRP IDRW IDV IDF9 IDF10 IDRK
     IDF8 IDF14 IDF7 INTRA1 IDSFC IDPF IDF13 CODP COKD COIM
     IDSKD IDSIM IDSDP INTER1 IDSC
     ;  PRINT @IFCONV;
?
?     PRINT THE RESULTS FROM ALL THREE METHODS.
?
TITLE 'COMPARE RESULTS FROM GAUSS, FLPOW, AND NEWTONS METHOD' ;
PAGE ;
DOT E KD RE RP RW V N NW RK
    LJ LD PDP SHRC CC PF PLD SHRDP SHRKD SHRIM L PL DP SHRFC PC;
  . = .SAV;   ? RESTORE ORIGINAL VARIABLES
  PRINT .N .S .F . ;
ENDDOT;