options crt;  ? 9e8
?
?  coded for TSP 4.4 or higher  (uses lagged EQSUB )
?  by Clint Cummins   rev. 11/21/1998 
in klem;
freq a;
smpl 47,71;
? Generalized Leontief   (for Translog, see below)
dot k l e m;
  a. = q./qy;
  pp = p.;
  dot k l e m;
    r.. = sqrt(pp/p.);  ? note:  rkk = 1, rll = 1, etc.
  enddot;
  param dk. dl. de. dm.;
enddot;
? R=0, with equations written in unnormalized form (as residuals).
? 
frml uk ak - ( dkk     + dkl*rlk + dke*rek + dkm*rmk ) ;
frml ul al - ( dkl*rkl + dll     + dle*rel + dlm*rml ) ;
frml ue ae - ( dke*rke + dle*rle + dee     + dem*rme ) ;
frml um am - ( dkm*rkm + dlm*rlm + dem*rem + dmm     ) ;
dot k l e m;
  frml e. u. - rho.*u.(-1);   ? rho-differenced residual
  param rho.;
  eqsub e. u.;
enddot;
smpl 48,71;
lsq(maxit=50) ek el ee em;  ? (a)
copy @logl lnl1;

lsq(maxit=100) uk ul ue um;  ? (b)
copy @logl lnl0;
set lr = 2*(lnl1-lnl0);
cdf(chisq,df=4) lr;

?
? Translog
smpl 47,71;
tc = 0;
dot k l e m;
  v. = p.*q.;
  tc = tc + v.;
enddot;
dot k l e;
  s. = v./tc;
  l.m = log(p./pm);
  param alpha.;
enddot;
? Unnormalized, with symmetry  (9.65)
frml uk sk - ( alphak + gkk*lkm + gkl*llm + gke*lem ) ;
frml ul sl - ( alphal + gkl*lkm + gll*llm + gle*lem ) ;
frml ue se - ( alphae + gke*lkm + gle*llm + gee*lem ) ;
param gkk gkl gke gll gle gee;
dot k l e;
  frml e. u. - rho*u.(-1);   ? rho-differenced residual
  eqsub e. u.;
enddot;
param rho;
smpl 48,71;
lsq ek el ee;  ? (a)
copy @logl lnl1;

lsq uk ul ue;  ? (b)
copy @logl lnl0;
set lr = 2*(lnl1-lnl0);
cdf(chisq,df=1) lr;