options crt;  ? 9e4
in klem;
freq a;
smpl 47,71;
tc = 0;
ly = log(qy);
dot k l e m;
  v. = p.*q.;
  tc = tc + v.;
  lp. = log(p.);
  frml es. s. = alpha. + g.k*lpk + g.l*lpl + g.e*lpe + g.m*lpm + g.y*ly;
  param alpha. g.k g.l g.e g.m g.y;
  set g.sum = 0;
enddot;
set alsum = 0;
set gysum = 0;
set sumvar = 0;
dot(index=i) k l e m;
  s. = v./tc;
  lsq es.;  ? (a.1)
  set alsum = alsum + alpha.;   ? for (a.2)
  set gksum = gksum + g.k;
  set glsum = glsum + g.l;
  set gesum = gesum + g.e;
  set gmsum = gmsum + g.m;
  set gysum = gysum + g.y;
  if (i<4); then;   ? check variance of sum
    set sumvar = sumvar + @vcov(2,2);
  else; do;
    title 'variance of GMK';
    print sumvar,@vcov(2,2);
  enddo;
enddot;
print alsum,gksum,glsum,gesum,gmsum,gysum;

title 'IZEF with M deleted';
dot k l e;
  l.m = log(p./pm);
enddot;
frml eq965a sk = alphak + gkk*lkm + gkl*llm + gke*lem;
frml eq965b sl = alphal + gkl*lkm + gll*llm + gle*lem;
frml eq965c se = alphae + gke*lkm + gle*llm + gee*lem;
frml eq965d sm = alpham + gkm*lkm + glm*llm + gem*lem;
lsq eq965a eq965b eq965c;  ? (b.1)
frml eq949a alpham = 1-alphak-alphal-alphae;
frml eq949b gkm = -(gkk+gkl+gke);
frml eq949c glm = -(gkl+gll+gle);
frml eq949d gem = -(gke+gle+gee);
frml eq949f gmm = gkk+gll+gee + 2*(gkl+gke+gle);
analyz eq949a eq949b eq949c eq949d eq949f;  ? (b.2)

title 'IZEF with K deleted';
dot l e m;
  l.k = log(p./pk);
enddot;
frml eq966a sl = alphal + gll*llk + gle*lek + glm*lmk;
frml eq966b se = alphae + gle*llk + gee*lek + gem*lmk;
frml eq966c sm = alpham + glm*llk + gem*lek + gmm*lmk;
lsq eq966a eq966b eq966c;  ? (b.3)
frml eqsum1 alphak = 1-alphal-alphae-alpham;
frml eqsum2 gkk = gll+gee+gmm + 2*(gle+glm+gem);
frml eqsum3 gkl = -(gll+gle+glm);
frml eqsum4 gke = -(gle+gee+gem);
frml eqsum5 gkm = -(glm+gem+gmm);
analyz eqsum1-eqsum5;  ? (b.4)

lsq eq965a eq965b eq965c eq965d;  ? (b.5)

title '3SLS, not invariant to dropped share';
3sls(inst=(c,z1-z10)) eq965a eq965b eq965c;  ? (c.1)
analyz eq949a eq949b eq949c eq949d eq949f;  ? (c.2)
3sls(inst=(c,z1-z10)) eq966a eq966b eq966c;  ? (c.3)
analyz eqsum1-eqsum5;  ? (c.4)

title '3SLS, invariant to dropped share (slow)';
3sls(inst=(c,z1-z10),maxit=500,maxitw=500,wname=own)
   eq965a eq965b eq965c;  ? (c.1b)
analyz eq949a eq949b eq949c eq949d eq949f;  ? (c.2b)
3sls(inst=(c,z1-z10),maxit=500,maxitw=500,wname=own)
   eq966a eq966b eq966c;  ? (c.3b)
analyz eqsum1-eqsum5;  ? (c.4b)