options crt;  ? 8e5
in causal;
freq q;
smpl 56:1,75:4;
adv = log(adn);  ? following Ashley et al. (1980)
cons = log(ucgn);
smpl 56:1,70:4;

bjident(ndiff=1,nsdiff=1) adv;
bjest(ndiff=1,nsdiff=1,nma=4,const,exactml,tol=1e-7,grad=c4,maxit=30)
     adv  zfix theta(1) zfix theta(3);
copy @res adve;  ? (a.1)
bjfrcst(nhoriz=20) adv;
rename @fit adv1;  ? for (e)

bjident(ndiff=1,nsdiff=1) cons;
bjest(ndiff=1,nma=5,const,exactml,tol=1e-7,grad=c4)
     cons  zfix theta(1) zfix theta(2) zfix theta(3) zfix theta(4);
copy @res conse;  ? (a.2)
bjfrcst(nhoriz=20) cons;
rename @fit cons1;  ? for (e)

? Cross-correlations of residuals
? (just look at the first column of this)
smpl 56:1,70:4;
corr(pair) adve conse(-7)-conse(+7);  ?  (b.1)
ar1 adve conse(-1);  ?  (b.2)

?
?  TSP 4.4 does not currently have the built in capability to estimate
?  transfer function models, so we will just use a plain regression
?  for now, ignoring the MA(q) residuals.  We could do a separate
?  BJEST(NMA=q) estimation on the residuals, to get a bit closer
?  to a full estimation strategy.
?
smpl 56:2,75:4;
dadv = adv-adv(-1);
smpl 57:2,70:4;
olsq dadv c dadv(-1) dadv(-2) cons(-1)-cons(-5);  ? less restricted form
olsq dadv c dadv(-1) dadv(-2) cons(-1) cons(-5);  ? (8.49) w/o MA(2) res  (c)
smpl 71:1,75:4;
forcst(static) dadv2;
adv2 = adv(-1) + dadv2;  ? for (e)

smpl 56:2,75:4;
dcons = cons-cons(-1);
smpl 57:2,70:4;
dd4cons = dcons-dcons(-4);
olsq dd4cons c dadv;  ? (8.50) w/o MA(4) res  (d)
smpl 71:1,75:4;
forcst(static) ddcons2;
dcons2 = dcons(-4) + ddcons2;
cons2 = cons(-1) + dcons2;  ? for (e)

smpl 71:1,75:4;
actfit adv adv1;
actfit adv adv2;
actfit cons cons1;
actfit cons cons2;  ? (e)