options crt;  ? 8e4
in nichol;
freq a;
smpl 1931,1949;
sales = camels+lucky;
shcam = camels/sales;
shluc = lucky/sales;
wcam = reyadv/ameadv;
wluc = ameadv/reyadv;
print shcam shluc wcam wluc ameadv reyadv;  ? (a)

smpl 1932,1949;
olsq shcam c wcam rlinc shcam(-1);
copy @fit fitcam;
impluc = 1-fitcam;
print fitcam impluc;  ? (b)

smpl 1932,1949;
olsq shluc c wluc rlinc shluc(-1);
copy @fit fitluc;
impcam = 1-fitluc;
print fitluc impcam;  ? (c.1)
print fitcam impcam fitluc impluc;  ? (c.2-3)
sumsh = fitcam+fitluc;
msd(terse) sumsh;  ? (c.4)

lwcam = log(wcam);
lwluc = log(wluc);
olsq(silent) shcam c lwcam rlinc shcam(-1);
copy @fit fitcam;
olsq(silent) shluc c lwluc rlinc shluc(-1);
copy @fit fitluc;
sumshl = fitcam+fitluc;
msd(terse) sumshl;  ? (d.1)

totadv = reyadv + ameadv;
ashcam = reyadv/totadv;
ashluc = ameadv/totadv;
olsq(silent) shcam c ashcam rlinc shcam(-1);
copy @fit fitcam;
olsq(silent) shluc c ashluc rlinc shluc(-1);
copy @fit fitluc;
sumshash = fitcam+fitluc;
msd(terse) sumshash;  ? (d.2)

smpl 1931,1949;
sales = camels+lucky+chest;
shcam = camels/sales;
shluc = lucky/sales;
shche = chest/sales;
wcam = reyadv/(ameadv+ligadv);
wluc = ameadv/(reyadv+ligadv);
wche = ligadv/(reyadv+ameadv);
smpl 1932,1949;
sumsh = 0;
dot cam luc che;   ? use dot loop to cut down on repetitive typing
  olsq(silent) sh. c w. rlinc sh.(-1);
  sumsh = sumsh + @fit;
enddot;
msd(terse) sumsh;  ? (e)

smpl 1931,1949;
totadv = reyadv + ameadv + ligadv;
ashcam = reyadv/totadv;
ashluc = ameadv/totadv;
ashche = ligadv/totadv;
smpl 1932,1949;
sumshl = 0;
sumshash = 0;
dot cam luc che;   ? use dot loop to cut down on repetitive typing
  lw. = log(w.);  ? redefine lw., since w. have been redefined
  olsq(silent) sh. c lw. rlinc sh.(-1);
  sumshl = sumshl + @fit;
  olsq(silent) sh. c ash. rlinc sh.(-1);
  sumshash = sumshash + @fit;
enddot;
msd(terse) sumshl sumshash;  ? (f)