options crt;  ? 8e3  (annual at top, monthly at bottom)
?------------
? Annual data
?------------
in palda;
freq a;
smpl 1912,1960;
olsq sales c sales(-1) adver dum1-dum3;  ? (a)

ar1 sales c adver dum1-dum3;  ? (b)

?
? Testing lagged dependent vs. AR(1).  This test is automated
? as the WNLAR test (Wald NonLinear AR) in regopt, also known as
? a "common factor" test.  So the easiest way to compute it is:
?
regopt(pvprint) wnlar;
olsq sales c adver dum1-dum3;  ? (c)
regopt;
?
? To compute it by hand, run the expanded regression, plus ANALYZ.
? Part (c) forgets to mention that the lagged dummies are also
? technically needed.
olsq sales c adver adver(-1) sales(-1) dum1-dum3 dum1(-1) dum2(-1) dum3(-1);
frml r1 adver*sales(-1) + adver(-1);  ? should be zero for AR(1) model
frml r2 dum1*sales(-1) + dum1(-1);
frml r3 dum2*sales(-1) + dum2(-1);
frml r4 dum3*sales(-1) + dum3(-1);
analyz r1-r4;  ? (c)

?   "brand loyalty" model
?  method=corc will be used, since TSP sees the lagged dependent variable
ar1 sales c sales(-1) adver dum1-dum3;  ? (d)

?-------------
? Monthly data
?-------------
freq m;
smpl 1907:1,1926:12 1937:1,1960:6;
in palda;  ? to read in dum1-dum3, if above annual code is not used
dot 1-3;
  convert mdum. = dum.;
enddot;
in paldam;
smpl 1907:3,1926:12 1937:3,1960:6;
olsq msales c msales(-1) madv mdum1-mdum3;  ? (a)

ar1 msales c madv mdum1-mdum3;  ? (b)

?
? Testing lagged dependent vs. AR(1).  This test is automated
? as the WNLAR test (Wald NonLinear AR) in regopt, also known as
? a "common factor" test.  So the easiest way to compute it is:
?
regopt(pvprint) wnlar;
olsq msales c madv mdum1-mdum3;  ? (c)
regopt;
?
? To compute it by hand, run the expanded regression, plus ANALYZ.
? Part (c) forgets to mention that the lagged dummies are also
? technically needed.
olsq msales c madv madv(-1) msales(-1) mdum1-mdum3
            mdum1(-1) mdum2(-1) mdum3(-1);
frml r1 madv*msales(-1) + madv(-1);  ? should be zero for AR(1) model
frml r2 mdum1*msales(-1) + mdum1(-1);
frml r3 mdum2*msales(-1) + mdum2(-1);
frml r4 mdum3*msales(-1) + mdum3(-1);
analyz r1-r4;  ? (c)

?   "brand loyalty" model
?  method=corc will be used, since TSP sees the lagged dependent variable
ar1 msales c msales(-1) madv mdum1-mdum3;  ? (d)