options crt;  ? 8e2
in palda;
freq a;
smpl 1908,1960;
as = adver/sales;
print as;
msd as;   ? (a.1) - annual
in paldam;
freq m;
smpl 1907:1,1926:12 1937:1,1960:6;
mas = madv/msales;
print mas;
msd mas;   ? (a.2) - monthly

in palda;
freq a;
smpl 1908,1960;
olsq sales c sales(-1) adver dum1-dum3;  ? (b)
set alamfull = @coef(2);

frml aeq m = 12*log(1-p)/log(sales(-1));  ? duration interval in months
set p = .9;
analyz aeq;  ? (c)
set amfull = m;

smpl 1908,1926 1938,1960;  ? It's not entirely clear in the phrasing of
     ? this exercise whether the two periods 1908-26 and 1938-60 should
     ? be together in the same regression, or in separate regressions.
olsq sales c sales(-1) adver dum1-dum3;
set alam = @coef(2);
analyz aeq;
set am = m;
print alamfull alam amfull am;  ? (d)

in paldam;
freq m;
smpl 1907:1,1926:12 1937:1,1960:6;
dot 1-3;
  convert mdum. = dum.;
enddot;
smpl 1907:2,1926:12 1937:2,1960:6;
olsq msales c msales(-1) madv mdum1-mdum3;
set mlam = @coef(2);
frml meq m = log(1-p)/log(msales(-1));
analyz meq;
set mm = m;
print alam mlam am mm;  ? (e)

freq q;
smpl 1907:1,1926:4 1937:1,1960:2;
convert(sum) qsales = msales;
convert(sum) qadv = madv;
dot 1-3;
  convert(ave) qdum. = mdum.;
enddot;
smpl 1907:2,1926:4 1937:2,1960:2;
olsq qsales c qsales(-1) qadv qdum1-qdum3;
set qlam = @coef(2);
frml qeq m = 3*log(1-p)/log(qsales(-1));
analyz qeq;
set qm = m;
print alam mlam qlam am mm qm;  ? (f)