options crt;  ? 6e3
in kopcke;
freq q;
smpl 56:1,79:4;
?  Note:  8 lags is for structures, not equipment (error in exercise 3a/c)
olsq is c is(-1)-is(-8);  ? note shorthand for list of lags
rmse is %s1;              ? call the RMSE procedure defined below
smpl 56:1,86:4;
olsq is c is(-1)-is(-8);  ? (a)
rmse is %s2;
print %s1 %s2;            ? (b)
?
smpl 56:1,79:4;
?  Note:  6 lags is for equipment, not structures (error in exercise 3a/c)
olsq ie c ie(-1)-ie(-6);
rmse ie %e1;
smpl 56:1,86:4;
olsq ie c ie(-1)-ie(-6);
rmse ie %e2;
print %e1 %e2;            ? (c)
?
?  Use the @SBIC value to choose lag lengths
?
mform(nrow=12,ncol=1) msbice=0;
dot sbics sumbe sumbs;
 copy msbice m.;   ? make several 12 x 1 matrices to store results
enddot;
do m=1,12;
  set mm = -m;
  dot e s;
    olsq(silent) i. c i.(-1)-i.(mm);
    set msbic.(m) = @sbic;
    mat sumb = sum(@coef) - @coef(1);
    set msumb.(m) = sumb;
  enddot;
enddo;
freq n; smpl 1,12;
dot sbice sbics sumbe sumbs;
 unmake m. . ;   ? convert matrices to series for table printing
enddot;
print sbice sbics sumbe sumbs;  ? (d) -- look for min of sbic.
?
? here we define the RMSE procedure
?
proc rmse y %rmse;
 local e %ssr;
 e = @res/y;
 mat %ssr = e'e;
 set %rmse = sqrt(%ssr/@nob);
endproc;