options crt;  ? 4e3
in chow;
smpl 1,137;
mem = words*binary*digits;
dot rent mult access add mem;
  ln. = log(.);
enddot;
dot(value=jyr) 61-65;   ? jyr = 61 to 65
  d. = (year = jyr);    ? Create dummy variable with a "logical expression"
enddot;
d5459 = (year >= 54 & year <= 59);   ? more logical expressions
d6065 = (year >= 60 & year <= 65);
select d6065;
corr lnrent lnmult lnaccess lnadd lnmem;
select d5459;
corr lnrent lnmult lnaccess lnadd lnmem;  ? (a)
?
select d6065;
olsq lnrent c d61-d65 lnmult lnmem lnaccess;
 rename @ssr ssrest;
unmake @coef b1-b9;
mmake dcoef 0 b2-b6;
freq a;
smpl 60,65;
unmake dcoef estcoef;
priceind = exp(estcoef);
print estcoef priceind;  ? (b)
?
freq n;
smpl 1,137;
select d6065;
lnlength = log(binary*digits);
lnwords = log(words);
olsq lnrent c d61-d65 lnmult lnlength lnwords lnaccess;
 rename @ssr ssunr;
set df1 = 1;
set df2 = @nob-10;
set fstat1 = (ssrest-ssunr)/(ssunr/df2);
cdf(f,df1=df1,df2=df2) fstat1;  ? (c)
?  alternative t-tests
olsq(silent) lnrent c d61-d65 lnmult lnmem lnwords lnaccess;
 rename @ssr ssunr2;
set fstat2 = @t(9)**2;
olsq(silent) lnrent c d61-d65 lnmult lnmem lnlength lnaccess;
 rename @ssr ssunr3;
set fstat3 = @t(9)**2;
print fstat1,fstat2,fstat3,ssunr,ssunr2,ssunr3;
?
select 1;
set jyr = 55;
dot 55-60;
  d. = (year = jyr);
  set jyr = jyr+1;
enddot;
olsq lnrent c d55-d65 lnmult lnmem lnaccess;
unmake @coef b1-b15;
mmake dcoef 0 b2-b12;
freq a;
smpl 54,65;
unmake dcoef estcoef;
priceind = exp(estcoef);
set p65 = priceind(65);
pi65 = priceind/p65*100;
print estcoef priceind pi65;  ? (d)
?
freq n;
smpl 1,137;
select d6065;
olsq(weight=volume) lnrent c d61-d65 lnmult lnmem lnaccess;