options crt;  ? 4e2
in waugh;
smpl 1,200;
corr price green nostalks disperse;  ? (a)
supres @logl @coef;
olsq(silent) price c green;
 set rpg = sqrt(@rsq);  rename @rsq r2pg;
olsq(silent) price c nostalks;
 set rpn = sqrt(@rsq);  rename @rsq r2pn;
olsq(silent) price c disperse;
 set rpd = sqrt(@rsq);  rename @rsq r2pd;
print rpg rpn rpd;  ? (b)
?
olsq(silent) price c green nostalks;
 set rgn = @corr(2,3);
 print r2pg @rsq rgn;
olsq(silent) price c green disperse;
 set rgd = @corr(2,4);
 print r2pg r2pd @rsq rgd;
olsq(silent) price c nostalks disperse;
 set rnd = @corr(3,4);
 print r2pn r2pd @rsq rnd;  ? (c)
?
olsq(silent) price c green nostalks disperse;
 unmake @coef b0 b1 b2 b3;
 rename @fit pfit;
 rename @rsq r2pgnd;
 set r2sum = r2pg + r2pn + r2pd;
 print r2pgnd r2sum;  ? (d)
?
olsq(silent) green c price;
 set dgreen = @coef(2)*b1;
 set wgreen = @coef(2)*.13826;
olsq(silent) nostalks c price;
 set dnostalk = @coef(2)*b2;
 set wnostalk = @coef(2)*(-1.53394);
olsq(silent) disperse c price;
 set ddispers = @coef(2)*b3;
 set wdispers = @coef(2)*(-.27553);
title 'coefficients of determination from current regressions';
print dgreen dnostalk ddispers;  ? (e)
title 'coefficients of determination using Waugh coefficients';
print wgreen wnostalk wdispers;  ? (e)
? We can use Waugh's variance-covariance matrix on p.133 to
? reproduce the last 2 coefs of determination, as indicated on p.135.
 set wgreen = .13826*3430.89/1063.64;
 set wnostalk = -1.53394*(-100.92)/1063.64;
 set wdispers = -.27553*(-82.35)/1063.64;
title 'coefficients of determination using Waugh coefs and vcov';
print wgreen wnostalk wdispers;  ? (e)
?
nosupres;
olsq price c pfit;
 print @rsq r2pgnd;  ? (f)