options crt;  ? 3e9
in nerlov;
smpl 1,145;
lncp3 = log(costs/pf);
lnp13 = log(pl/pf);
lnp23 = log(pk/pf);
lnkwh = log(kwh);
group = int(order/100);  ? 1,2,3,4,5 for groups
?
?   splice in update data for next 99 obs.
?
in update;
smpl 146,244;
lncp3 = log(cost70(-145)/pf70(-145));
lnkwh = log(kwh70(-145));
lnp13 = log(pl70(-145)/pf70(-145));
lnp23 = log(pk70(-145)/pf70(-145));
trend t;
group = 6+int((t-1)/20);  ? groups 6-10
?
smpl 1,244;
?
? The easiest way to do these F-tests for pooling is with the
? Panel command, comparing BYID and TOTAL.  The F-test is labelled
? Ai,Bi vs. A,B .
?
select group <= 5;
panel(id=group,byid,nobet,nowithin,novarc) lncp3 c lnkwh lnp13 lnp23;  ? (a)
select group > 5;
panel(id=group,byid,nobet,nowithin,novarc) lncp3 c lnkwh lnp13 lnp23;  ? (b)
select 1;
panel(id=group,byid,nobet,nowithin,novarc) lncp3 c lnkwh lnp13 lnp23;  ? (c.1)
?
? The final tests (groups 1-5 vs. 6-10) can be done with a simple
? split-sample Chow test.
regopt(chowdate=146) chow;
olsq lncp3 c lnkwh lnp13 lnp23;  ? (c.2)
lny2 = lnkwh**2;
olsq lncp3 c lnkwh lny2 lnp13 lnp23;  ? (d)
?
? We can also compute them "by hand" -- a bit more effort, but
? the econometrics is fairly basic.  Note the different names for
? the different tests, so that we can distinguish the results in
? the output file.
?
dummy group;
set ssr55t = 0;
dot 1-5;
  select group.;
  olsq(silent) lncp3 c lnkwh lnp13 lnp23;
   set ssr55t = ssr55t + @ssr;
enddot;
select group <= 5;
olsq(silent) lncp3 c lnkwh lnp13 lnp23;
 rename @ssr ssr55;
set df1 = 4*4;
set df2 = @nob-4*5;
set f1_5 = (ssr55-ssr55t)/df1/(ssr55t/df2);
cdf(f,df1=df1,df2=df2) f1_5;  ? (a)
?
set ssr70t = 0;
dot 6-10;
  select group.;
  olsq(silent) lncp3 c lnkwh lnp13 lnp23;
   set ssr70t = ssr70t + @ssr;
enddot;
select group > 5;
olsq(silent) lncp3 c lnkwh lnp13 lnp23;
 rename @ssr ssr70;
set df1 = 4*4;
set df2 = @nob-4*5;
set f6_10 = (ssr70-ssr70t)/df1/(ssr70t/df2);
cdf(f,df1=df1,df2=df2) f6_10;  ? (b)
?
select 1;
olsq(silent) lncp3 c lnkwh lnp13 lnp23;
 rename @ssr ssr5570;
set df1 = 4*9;
set df2 = @nob-4*10;
set f1_10 = (ssr5570-ssr55t-ssr70t)/df1/((ssr55t+ssr70t)/df2);
cdf(f,df1=df1,df2=df2) f1_10;   ? (c.1)
?
set df1 = 4;
set df2 = @nob-4*2;
set f55_70c = (ssr5570-ssr55-ssr70)/df1/((ssr55+ssr70)/df2);
cdf(f,df1=df1,df2=df2) f55_70c;  ? (c.2)
?
lny2 = lnkwh*lnkwh;
select group <= 5;
olsq lncp3 c lnkwh lny2 lnp13 lnp23;
 rename @ssr ss55;
select group > 5;
olsq lncp3 c lnkwh lny2 lnp13 lnp23;
 rename @ssr ss70;
select 1;
olsq lncp3 c lnkwh lny2 lnp13 lnp23;
 rename @ssr ss5570;
set df1 = 5;
set df2 = @nob-5*2;
set f55_70d = (ss5570-ss55-ss70)/df1/((ss55+ss70)/df2);
cdf(f,df1=df1,df2=df2) f55_70d;  ? (d)