options crt;  ? 3e8
in nerlov;
smpl 1,145;
lncp3 = log(costs/pf);
lnp13 = log(pl/pf);
lnp23 = log(pk/pf);
lnkwh = log(kwh);
title 'default upper bound on DW P-value';
title '(this is enough to reject at 95% level)';
ols lncp3 c lnkwh lnp13 lnp23;  ? (a)
copy %dw %dwupbnd;

title 'exact DW P-value';
title '(this shows the upper bound is good)';
regopt(dwpvalue=exact);
ols lncp3 c lnkwh lnp13 lnp23;  ? (a)
print @dw %dwupbnd %dw;

? Although the Durbin-Watson is highly significant, so
? is the Jarque-Bera non-normality test, so probably the
? Durbin-Watson is just picking up the effect of all the
? large positive residuals in the initial 12 or so observations.

trend obs;
select obs <= 12;
print @res;
select 1;
plot lncp3 y @fit f;
? The graphs below suggest that a quadratic term in lnkwh
? might improve the fit (reduce large residuals at both ends
? of the sample).  This is also suggested by the highly significant
? RESET-2 regression diagnostic.
graph @res lnkwh;
graph @res lnp13;
graph @res lnp23;
lnkwh2 = lnkwh**2;
?
? When we add the quadratic term, the RESET-2 test becomes
? insignificant, and the Durbin-Watson and Jarque-Bera become
? less significant (although still significant at the 95% level).
? So it appears to be a good improvement to the functional form.
ols lncp3 c lnkwh lnp13 lnp23 lnkwh2;

? The LM Heteroskedasticity test is also significant,
? which shows the size of the residuals is related to the
? scale of the RHS variables.  So it is really a functional form
? problem or a heteroskedasticity problem rather than
? an autocorrelation problem.
? When we run AR1 below, the results are about the same as OLS.

ar1 lncp3 c lnkwh lnp13 lnp23;

? It might also be fun to run the LAD and LMS commands to see if
? any outliers are detected.  The LMS output indicates about 18 outliers,
? including 11 of the first 12 observations.

lad lncp3 c lnkwh lnp13 lnp23;
lms(print) lncp3 c lnkwh lnp13 lnp23;

? Also look for outliers in the model where the quadratic for lnkwh
? is added.  The number of outliers is about the same as before, but
? there are not so many large outliers, so this model appears to
? be an improvement.
lms(print) lncp3 c lnkwh lnp13 lnp23 lnkwh2;