options crt;  ? 2e9
in return;
freq m;
smpl 77:12 87:12;
 rpoil = poil/cpi;
smpl 78:1 87:12;
 rinf = (cpi-cpi(-1))/cpi(-1);
 roil = (rpoil-rpoil(-1))/rpoil(-1);
 gind = (frbind-frbind(-1))/frbind(-1);
msd rinf roil gind;
 surinf = rinf - @mean(1);
 suroil = roil - @mean(2);
 surind = gind - @mean(3);
?
?  Note:  the means do not actually have to be removed to perform
?  the F-tests, because the means will be absorbed by the free
?  constant term in the equation.  If the model for surprise was
?  not so simple, this would no longer be true.
?
 ?print surinf suroil surind;  ? (a)
?
rpmark = market - rkfree;
supres logl;
set nrest = 3;
dot mobil texaco ibm dec datgen coned psnh weyer boise
    motor tandy panam delta contil citcrp gerber genmil;
 rp. = . - rkfree;
 olsq rp. c rpmark surinf suroil surind;  rename @ssr ssunr;
 olsq(silent) rp. c rpmark;  rename @ssr ssrest;
 set dfunr = @nob - 5;
 set fstat = ((ssrest-ssunr)/nrest) / (ssunr/dfunr);
 cdf(f,df1=nrest,df2=dfunr) fstat;  ? (b)
enddot;