options crt;  ? 2e8
in return;
freq m;
smpl 78:1 87:12;
dummy(exclude);  ? this makes monthly dummies M1-M11
rename m1 dumj;
nonjan = 1-dumj;
rpmark = market - rkfree;
set nrest = 2;
supres ssr s ymean sdev nob dw rsq arsq fst logl;  ? cut down on reg. output
dot mobil texaco ibm dec datgen coned psnh weyer boise
    motor tandy panam delta contil citcrp gerber genmil;
  olsq . c dumj;                   ? (c)
  set nobtot = @nob;
  rp. = . - rkfree;
  olsq(silent) rp. c rpmark;  rename @ssr ssrest;
 select dumj;
  olsq(silent) rp. c rpmark;  rename @ssr ssunr1;
 select nonjan;
  olsq(silent) rp. c rpmark;  rename @ssr ssunr2;
  set dfunr = nobtot-4;
  set ssunr = ssunr1+ssunr2;
  set fstat = ((ssrest-ssunr)/nrest) / (ssunr/dfunr);
  cdf(f,df1=nrest,df2=dfunr) fstat;         ? (d)
 select 1;
  olsq(silent) rp. c rpmark dumj;  ? (e)
  set nob3 = nobtot-3;
  cdf(t,df=nob3,twotail) @t(3);  ? two-tail - for "null: January same,
                                 ?    alternative: January different"
                                 ? Actually redundant, since this P-value
                                 ? is computed by the above regression.
  cdf(t,df=nob3,uptail) @t(3);  ? upper tail - for "null: January same,
                                ?    alternative: January better"
                                ? (the null was misstated in the text)
 supres smpl;  ? turn off remaining SMPL output
enddot;