options crt;  ? 11e4
in mroz;   ? contains PRIN and LWW1 if 11e1 has been run

title 'Exercise 2, part (a) - conditional OLS - Proc. II';
select lfp;
olsq(robust) whrs c kl6 k618 wa we lww1 prin;
copy @coef bols;
? Note:  the robust SEs here use HCTYPE=2, which do not exactly
? match Mroz's results (computed with HCTYPE=1).  The HCTYPE=1
? option in OLSQ can be used to reproduce Mroz's results:
?olsq(robust,hctype=1) whrs c kl6 k618 wa we lww1 prin;

title 'Exercise 2, part (b) - transformed OLS estimates';
set p = 428/753;
mat bolst = bols/p;
mat vcov = @vcov/p**2;
tstats(names=@rnms) bolst vcov;

title 'Exercise 2, part (c) - ML Tobit - Proc. III';
select 1;
tobit whrs c kl6 k618 wa we lww1 prin;
title 'comparing Tobit with transformed OLS';
unmake @coef b1-b7 sigma;
mmake btob b1-b7;
mmake tob_olst btob bolst;
print tob_olst;

title 'Exercise 2, part (d) - McDonald-Moffitt decomposition';
set z = cnormi(p);
set fz = norm(z);
title 'change in hours from those already working';
set A = 1 - z*fz/p - (fz/p)**2;
set dHsdLW = b6*A;
set FzdHsdLW = p*dHsdLW;
print FzdHsdLW;
title 'change in hours from new workers';
msd(noprint) c kl6 k618 wa we lww1 prin;
mat xb = @mean'btob;
set EHs = xb + sigma*fz/p;
set dFzdLW = fz*b6/sigma;
set EHsdFdLW = EHs*dFzdLW;
print EHsdFdLW;
title 'proportion of change in hours from those already working';
print A;

title 'Exercise 2, part (e) - Tobit on positive observations';
select lfp;
tobit whrs c kl6 k618 wa we lww1 prin;
title 'comparing positive Tobit with OLS';
unmake @coef b1-b7 sigma;
mmake btobp b1-b7;
mmake tobp_ols btobp bols;
print tobp_ols;