options crt;  ? 11e3
in mroz;   ? contains PRIN and LWW1 if 11e1 has been run

title 'Exercise 3, part (a) - linear probability model';
olsq lfp c lww1 kl6 k618 wa we un cit prin;
copy @coef bols;
select @fit < 0;  print @fit;
select @fit > 1;  print @fit;
select 1;

title 'Exercise 3, part (b) - logit';
logit lfp c lww1 kl6 k618 wa we un cit prin;
copy @coef blogit;
title 'comparing OLS and rescaled LOGIT coefficients';
mat blogr = .25*blogit;
set blogr(1) = blogr(1) + .5;  ? intercept
set blogr(8) = blogr(8) + .5;  ? CIT - dummy variable
mmake ols_logr bols blogr;
print ols_logr;

title 'Exercise 3, part (c) - probit';
probit lfp c lww1 kl6 k618 wa we un cit prin;
copy @coef bprobit;

title 'Exercise 3, part (d) - probability derivatives';
title 'at P = sample mean';
  set p = @ymean;
  probder;
title 'probability derivatives at P = .9';
  set p = .9;
  probder;
Proc probder;
  set z = cnormi(p);
  set fz = norm(z);
  print p fz;
  mat dplog = (p*(1-p))*blogit;
  mat dprob = fz*bprobit;
  mmake dplog_prb dplog dprob;
  print dplog_prb;
endproc;

title 'Exercise 3, part (e) - PROBIT and rescaled LOGIT coefs';
set pi = 4*atan(1);  ? tan(pi/4) = 1
mat blog3pi = blogit*(sqrt(3)/pi);
mat blog625 = blogit*.625;
mmake pr_3p_62 bprobit blog3pi blog625;
print pr_3p_62;