options crt;  ? 10e8
in klein;
freq a;
smpl 20,41;
t = year-1931;
w = w1+w2;
y = cn+i+g-tx;
k = klag+i;
?
?  KLEIN-I,  USING BERNDT COEFFICIENT NAMES
?
FRML CON   CN = A0 + A1*W + A2*P + A3*P(-1);
FRML INV    I = B0 + B1*P + B2*P(-1) + B3*KLAG;
FRML WAGES W1 = G0 + G1*E + G2*E(-1) + G3*T;
IDENT TPROD Y = CN + I + G - TX;   ? most useful normalization
IDENT INC   P = Y - W1 - W2;       ? most useful normalization
IDENT KAP   K = KLAG + I;
IDENT WBILL W = W1 + W2;
IDENT PPROD E = Y + TX - W2;
?
SMPL 21,41 ;
PARAM A0-A3 B0-B3 G0-G3;
?
?  Run 3SLS first to get starting values for FIML
list ivs c p(-1) klag e(-1) t tx g w2;
3SLS(INST=ivs) CON INV WAGES;
?
?  Notes:
?  - Berndt's FIML results in Table 10.3 are incorrect (I don't know why).
?  - Correct results are given in Calzolari and Panattoni, Econometrica
?    (1988), p.702.  They are reproduced below.
?  - Special TOL and MAXIT options are used below to make FIML iterate
?    far enough to agree with these published results to 4 digits.
FIML(ENDOG=(CN,I,W1,Y,P,K,W,E),TOL=.000001,MAXIT=200)
   CON INV WAGES TPROD INC KAP WBILL PPROD;  ? (a)
copy @logl loglf;
?
?   TRUE FIML ESTIMATES OF COEFFICIENTS
?     FROM CALZOLARI AND PANATTONI.
?     LogL = -83.3238
?PARAM A0 18.34 A1 .8018 A2 -.2324 A3 .3857
?      B0 27.26 B1 -.8010 B2 1.052 B3 -.1481
?      G0 5.794 G1 .2341 G2 .2847 G3 .2348 ;
?
? Reduced form is solved for below. (b)
?  Note:  this is difficult.
? I didn't find the steps suggested in the book to be very helpful.
? Here's what I did instead:
? 1. Substitute all identities into the first 3 equations.
?   (The KAP identity is not needed, since it has no RHS endogenous vars.)
? 2. Write the model as  Y*J = X*B + E  , where J is the Jacobian matrix
? 3. The reduced form is   Y = X*B*J" + residual  .
? So our task is to obtain J, J" (J inverse), B, and B*J"  .
?
? In detail:
? 1. Substitute identities:
?   cn = a0 + a1*(w1+w2) + a2*(cn+i+g-tx-w1-w2) + a3*p(-1)
?    i = b0 + b1*(cn+i+g-tx-w1-w2) + b2*p(-1) + b3*klag
?   w1 = g0 + g1*(cn+i+g-tx+tx-w2) + g2*e(-1) + g3*t
? 2. collect the endogenous variables to the LHS, to find J:
?   cn*(1-a2) + i*a2     + w1*(a2-a1) = a0 + ...  (see below for RHS)
?   cn*(-b1)  + i*(1-b1) + w1*b1      = b0 + ...
?   cn*(-g1)  + i*(-g1)  + w1*1       = g0 + ...
?  So J is the matrix:
?    1-a2    a2     a2-a1
?    -b1     1-b1   b1
?    -g1     -g1    1
?  We can compute the determinant of J by taking the top row, and multiplying
?  each element by its cofactor.  (The cofactor is the determinant of the
?  submatrix where the row and column corresponding to the particular
?  element are removed).  For example, for the (1,1) element, the cofactor
?  is the determinant of  1-b1   b1   =  (1-b1)*1 - (-g1)*b1 = 1-b1+g1*b1 .
?                         -g1    1
?  (There is also the matter of signs of the cofactors)
?  So we can write the determinant of J as:
?   detj = (1-a2)*[1-b1+g1*b1] + a2*[b1-b1*g1] + (a2-a1)*[g1]
?  This simplifies to the expression below.
?
? determinant of Jacobian
frml detj g1*(a2-a1+b1) + 1-a2-b1;
?
? elements of inverse Jacobian  (with 1/detj factored out)
? (these are the cofactors of the elements of J)
? i1cn i1i i1w1
? i2cn i2i i2w1
? i3cn i3i i3w1
?
frml i1cn 1-b1+b1*g1;
frml i2cn a2-g1*(a2-a1);
frml i3cn a1*(1-b1)-a2;
frml i1i b1-b1*g1;
frml i2i 1-a2+g1*(a2-a1);
frml i3i b1*(a1-1);
frml i1w1 g1;
frml i2w1 g1;
frml i3w1 1-a2-b1;
?
dot cn i w1;
  frml eq. . = ( cf + p1f*p(-1) + k1f*klag + e1f*e(-1) + tf*t + txf*tx +
                 gf*g + w2f*w2 )/detj;
  ?
  ?   Calculate the coefficients for the reduced form for a particular
  ? equation -- this will be a row of the B*J" matrix.
  ?   B are the coefficients of the exogenous variables (C, P(-1), KLAG, etc.)
  ? in the equations after identities were substituted in.  For example,
  ? the RHS of the CN equation is
  ?  A0 + A3*P(-1) + (-A2)*TX + A2*G + (A1-A2)*W2  .
  ? i1., i2., and i3. are a column of J" corresponding to the dependent
  ? variable of the reduced form.  We multiply the equations by
  ? substituting the expressions for i1., i2., and i3. .
  ?
  frml cf       A0*i1. + B0*i2. + G0*i3.;   ? B*J" (*detJ)
  frml p1f      A3*i1. + B2*i2.         ;
  frml k1f               B3*i2.         ;
  frml e1f                        G2*i3.;
  frml tf                         G3*i3.;
  frml txf     -A2*i1. - B1*i2.         ;
  frml gf       A2*i1. + B1*i2. + G1*i3.;
  frml w2f (A1-A2)*i1. - B1*i2. - G1*i3.;
  ?
  ?  This makes the reduced form equation, for use by LSQ.
  eqsub eq. cf p1f k1f e1f tf txf gf w2f   i1. i2. i3. detj;
  ?
  ?  These equations are for the reduced form coefficients.
  ?  We can evaluate them directly, using ANALYZ.
  frml q.1 .cfb  = cf  /detj;  eqsub q.1 cf  i1. i2. i3. detj;
  frml q.2 .p1fb = p1f /detj;  eqsub q.2 p1f i1. i2.     detj;
  frml q.3 .k1fb = k1f /detj;  eqsub q.3 k1f     i2.     detj;
  frml q.4 .e1fb = e1f /detj;  eqsub q.4 e1f         i3. detj;
  frml q.5 .tfb  = tf  /detj;  eqsub q.5 tf          i3. detj;
  frml q.6 .txfb = txf /detj;  eqsub q.6 txf i1. i2.     detj;
  frml q.7 .gfb  = gf  /detj;  eqsub q.7 gf  i1. i2. i3. detj;
  frml q.8 .w2fb = w2f /detj;  eqsub q.8 w2f i1. i2. i3. detj;
  ?
  analyz q.1-q.8;   ? compute rrf coefs and SEs from FIML VCOV
enddot;
?
?  (c) -- estimation of restricted reduced form
lsq(wname=own) eqcn eqi eqw1;  ? same as FIML, but diff SEs
print @logl loglf;
?
analyz qcn1-qcn8 qi1-qi8 qw11-qw18;   ? compute rrf coefs and SEs from LSQ VCOV
?
?  (d) -- Unrestricted reduced form, for comparison
var cn i w1 | c p(-1) klag e(-1) t tx g w2;
?
?  (e)  Likelihood ratio test
set lr = 2*(@logl-loglf);
cdf(chisq,df=12) lr;