options crt;  ? 10e7 - worked for both Klein I and Lucas-Rapping
title 'Exercise 7 - Klein I model';
in klein;
freq a;
smpl 20,41;
t = year-1931;
w = w1+w2;
?
?  KLEIN-I,  USING BERNDT COEFFICIENT NAMES
?
FRML CON   CN = A0 + A1*W + A2*P + A3*P(-1);
FRML INV    I = B0 + B1*P + B2*P(-1) + B3*KLAG;
FRML WAGES W1 = G0 + G1*E + G2*E(-1) + G3*T;
PARAM A0-A3 B0-B3 G0-G3;
list ivs c p(-1) klag e(-1) t tx g w2;
SMPL 21,41 ;

title 'Exercise 7, part (a) - 2SLS';
LSQ(INST=ivs) CON;
LSQ(INST=ivs) INV;
LSQ(INST=ivs) WAGES;

title 'Exercise 7, part (b) - 3SLS';
3SLS(INST=ivs) CON INV WAGES;

title 'Exercise 7, part (c) - I3SLS';
3SLS(INST=ivs,maxitw=20) CON INV WAGES;

?===============================================
title 'Exercise 7 - Lucas-Rapping model';
in lucas;
smpl 29,65;
y1 = log(n/pop);
y2 = log(ql*n/rgnp);
y3 = log(hw);
y4 = log(hw/ql);
x2 = log(rgnp/pop);
x3 = log(ql);
smpl 30,65;
x1 = log(pgnp/pgnp(-1));
x4 = log(rgnp/rgnp(-1));
y5 = log(hw/hw(-1));

list ivs c x1-x4 y1(-1) y2(-1) y3(-1);
frml lsupply y1 = b10 + b11*y3 + b12*y3(-1) + b13*x1 + b14*y1(-1);  ? (10.23)
frml ldemand y2 = b20 + b21*y4 + b22*y2(-1) + b23*x4;               ? (10.25)
param b10-b14 b20-b23;

title 'Exercise 7, part (a) - 2SLS';
LSQ(INST=ivs) lsupply;
LSQ(INST=ivs) ldemand;

title 'Exercise 7, part (b) - 3SLS';
3SLS(INST=ivs) lsupply ldemand;

title 'Exercise 7, part (c) - I3SLS';
3SLS(INST=ivs,maxitw=20) lsupply ldemand;