options crt;  ? 10e3
in taylor;
freq q;
smpl 53:1 75:4;
ydev = log(gnp/potgnp);
rm1 = log(m1/gnpdef);
smpl 53:1 75:3;
inf = log(gnpdef(+1)/gnpdef);
print ydev rm1 inf;
?plot(preview) ydev;
?plot(preview) rm1;
?plot(preview) inf;
msd(corr) ydev rm1 inf;  ? (a)

? (b)
list ist1 c m1     gnpdef     rm1     rm1(-1) ydev(-1) ydev(-2) inf(-1) time;
list ist2 c m1(-1) gnpdef(-1) rm1(-1) rm1(-2) ydev(-2) ydev(-3) inf(-2) time;

smpl 53:3 75:3;
2sls(inst=ist1) ydev c ydev(-1) ydev(-2) rm1 rm1(-1) inf time;
ols             ydev c ydev(-1) ydev(-2) rm1 rm1(-1) inf time;
2sls(inst=ist1) inf c inf(-1) ydev;
ols             inf c inf(-1) ydev;
accel = inf - inf(-1);
2sls(inst=ist1) accel c ydev;
ols             accel c ydev;  ? (c)

smpl 53:4 75:3;
2sls(inst=ist2) ydev c ydev(-1) ydev(-2) rm1 rm1(-1) inf time;
form(param,varpref=out_) eqout;  ? for (e)
2sls(inst=ist2) inf c inf(-1) ydev;
form(param,varpref=inf_) eqinf;
2sls(inst=ist2) accel c ydev;  ? (d)

smpl 53:3 75:3;
3sls(inst=ist1) eqout eqinf;
const inf_inf1,1;  ? to hold the coefficient on inf(-1) fixed at 1
3sls(inst=ist1) eqout eqinf;  ? (e)

smpl 53:1 75:3;
bjest(exactml,nma=1,constant) inf;
inffit = @fit;
bjest(exactml,nma=1,constant) ydev;
ydevfit = @fit;
smpl 53:4 75:3;
list ist2fit c m1(-1) gnpdef(-1) rm1(-1) rm1(-2) ydevfit(-2) ydevfit(-3)
     inffit(-2) time;
2sls(inst=ist2fit) ydevfit c ydevfit(-1) ydevfit(-2) rm1 rm1(-1) inffit time;
2sls(inst=ist2fit) inffit c inffit(-1) ydevfit;
accelfit = inffit - inffit(-1);
2sls(inst=ist2fit) accelfit c ydevfit;  ? (f)